Los años que comienzan en jueves y son (bisiestos), así como los que comienzan en viernes (que no son bisiestos), coincide en domingo el 25 de julio, para saber en Excel cuando una fecha coincide en cierto día de la semana, podemos usar la función DIASEM (núm_de_serie,[tipo]), que devuelve un número (del 1 al 7), correspondiente al día de la semana, poniendo tipo 2, devuelve (1 si el día de la semana es lunes, 2 martes, 3 miércoles, 4 jueves, 5 viernes, 6 sábado y 7 domingo), como se indica a continuación en los diferentes ejemplos que nos pueden servir de ayuda o referencia:
La celda A1 solo contiene el año y deseamos saber si el 25 de julio de ese año coincide a domingo, aplicamos la siguiente fórmula que nos devuelve un número correspondiente al día de la semana: =DIASEM(FECHA(A1;7;25);2) si el número es =7 sería domingo.
Añadiendo en la fórmula =7 obtendríamos un resultado de VERDADERO en caso de que fuese domingo o FALSO si es otro día de la semana: =DIASEM(FECHA(A1;7;25);2)=7
Se pude poner la fecha directamente en la fórmula (ejemplo: 25-7-2021): =DIASEM(FECHA(2021;7;25);2)=7
La celda A1 contiene una fecha (día, mes y año), diferente al 25 julio : =DIASEM(FECHA(AÑO(A1);7;25);2)=7
Si la celda A1 contiene la fecha con el día, mes y año igual al que deseamos, aplicamos la siguiente fórmula: =DIASEM(A1;2)=7
Los años bisiestos tienen 366 días (febrero 29). Para saber si un año es bisiesto y al mismo tiempo si el 25 de julio del mismo año corresponde a domingo.
Las siguientes fórmulas devuelven VERDADERO si se cumplen las condiciones en caso contrario FALSO:
Para comprobar si el año de la celda A1 es bisiesto y al mismo tiempo si el 25 de julio coincide en domingo, aplicamos la siguiente fórmula:
=Y(O(RESIDUO(A1;400)=0;Y(RESIDUO(A1;4)=0;RESIDUO(A1;100)<>0));DIASEM(FECHA(A1;7;25);2)=7)
En el siguiente ejemplo la celda A1 contiene una fecha con el día, mes y año:
=Y(O(RESIDUO(AÑO(A1);400)=0;Y(RESIDUO(AÑO(A1);4)=0;RESIDUO(AÑO(A1);100)<>0));DIASEM(FECHA(AÑO(A1);7;25);2)=7)
La celda A1 contiene la fecha con el día mes y año del 25 de julio, aplicamos la siguiente fórmula:
=Y(O(RESIDUO(AÑO(A1);400)=0;Y(RESIDUO(AÑO(A1);4)=0;RESIDUO(AÑO(A1);100)<>0));DIASEM(A1;2)=7)
Para saber si el año de la celda A1 si el mes de febrero tiene 29 días y el 25 de julio coincide a domingo:
=Y(DIA(FECHA(A1;2;29))=29;DIASEM(FECHA(A1;7;25);2)=7)
Si la celda A1 contiene una fecha con el día, mes y año, aplicamos la siguiente fórmula:
=Y(DIA(FECHA(AÑO(A1);2;29))=29;DIASEM(FECHA(AÑO(A1);7;25);2)=7)
Comprueba si el último día del mes de febrero es 29 y el 25 julio es domingo (celda A1 contiene solo año):
=Y(DIA(FIN.MES(FECHA(A1;2;1);0))=29;DIASEM(FECHA(A1;7;25);2)=7)
Aplicamos la siguiente fórmula si la celda A1 contiene una fecha con el día, mes y año:
=Y(DIA(FIN.MES(FECHA(AÑO(A1);2;1);0))=29;DIASEM(FECHA(AÑO(A1);7;25);2)=7)
Las siguientes fórmulas también nos devuelven VERDADERO en la que tiene que cumplirse 3 condiciones del año que se encuentra en la celda A, que son las siguientes:
1º condición el año de la celda A1 tiene que ser año bisiesto
2º condición el 25 de julo tiene que coincidir en domingo.
3º condición el día de semana del 1 de enero de año que se encuentra en la celda A1 tiene que ser jueves:
=Y(O(RESIDUO(A1;400)=0;Y(RESIDUO(A1;4)=0;RESIDUO(A1;100)<>0));DIASEM(FECHA(A1;7;25);2)=7;DIASEM(FECHA(A1;1;1);2)=4)
En el caso de que la celda A1 contenga una fecha con el día, mes y año, aplicamos la siguiente fórmula:
=Y(O(RESIDUO(AÑO(A1);400)=0;Y(RESIDUO(AÑO(A1);4)=0;RESIDUO(AÑO(A1);100)<>0));DIASEM(FECHA(AÑO(A1);7;25);2)=7;DIASEM(FECHA(AÑO(A1);1;1);2)=4)
si la celda A1 tiene una fecha con el día 1 de enero, se puede cambair la parte final de la fórmula por:=DIASEM(A1;2)=4
El calendario muestra don diferente formato los meses que tienen 5 viernes, sábados y domingos, por lo general casi todos los años tienen alguno, dependiendo del día de la semana por el que comienza el año, como se indica a continuación:
Los años que son bisiestos y comienza por:
Lunes (marzo)
Martes (agosto)
Miércoles (mayo)
Jueves (octubre)
Viernes (enero y julio)
Sábado (diciembre)
Domingo (ningún mes)
Los años que no son bisiestos y comienzan por:
Lunes (ningún mes)
Martes (marzo)
Miércoles (agosto)
Jueves (mayo)
Viernes (enero y octubre)
Sábado (julio)
Domingo (diciembre)
En las siguientes imágenes podemos ver calendarios de diferentes años en la que muestras estos días con diferente formato:
Imagen 1 de calendario (año bisiesto), empieza en viernes (tiene el mes de enero y julio con 5 viernes, sábados y domingos)
Imagen 2 de calendario (no es año bisiesto), empieza en viernes (tiene el mes de enero y octubre con 5 viernes, sábados y domingos)
imagen 3 de calendario (año bisiesto), empieza en jueves (tiene el mes de octubre con 5 viernes, sábados y domingos)
Con estos datos, sabiendo por el día de la semana en que comienza el año y si es un año bisiesto o no, sabríamos el mes que le correspondiente.
En las siguientes fórmulas se comprueba si el año es bisiesto y dependiendo de esto con la función ELEGIR, que se acompaña de un número índice que es obtenido de la función DIASEM y usando tipo 2 (devuelve del 1 al 7), 1 para lunes, 2 martes, 3 miércoles, 4 jueves, 5 viernes, 6 sábado y 7 domingo y de los 7 argumentos se obtiene el que corresponda según el orden que estén y si el año es bisiesto o no.
Fórmula 1: la celda A1 sólo contiene el año:
=SI(O(RESIDUO(A1;400)=0;Y(RESIDUO(A1;4)=0;RESIDUO(A1;100)<>0));ELEGIR(DIASEM(FECHA(A1;1;1);2);"marzo ";"agosto ";"mayo ";"octubre ";"enero y julio ";"diciembre ";"ninguno ");ELEGIR(DIASEM(FECHA(A1;1;1);2);"ninguno ";"marzo ";"agosto ";"mayo ";"enero y octubre ";"julio ";"diciembre "))
Fórmula 2: devuelve el mismo resultado, pero no se usa con la función DIASEM (tipo 2) cambia el resultado (ya que la anterior devolvía 1 en el caso que sea lunes y así devuelve 2 (1 para domingo, 2 lunes, 3 martes y así hasta 7 que es sábado, por lo tanto, no se pone tipo y se cambia en la fórmula el orden de los argumentos:
=SI(O(RESIDUO(A1;400)=0;Y(RESIDUO(A1;4)=0;RESIDUO(A1;100)<>0));ELEGIR(DIASEM(FECHA(A1;1;1));"ninguno ";"marzo ";"agosto ";"mayo ";"octubre ";"enero y julio ";"diciembre ");ELEGIR(DIASEM(FECHA(A1;1;1));"diciembre ";"ninguno ";"marzo ";"agosto ";"mayo ";"enero y octubre ";"julio "))
Fórmula 3: Se obtiene el mismo resultado, no se emplea la función ELEGIR, pero se aplican más condiciones según el mes si corresponde a cierto día, también comprueba si el mes de febrero tiene 28 o 29 días:
=SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=29;DIASEM(FECHA(A1;1;1);2)=5);"enero y julio ";)&SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=28;DIASEM(FECHA(A1;1;1);2)=5);"enero y octubre ";)&SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=29;DIASEM(FECHA(A1;10;1);2)=5);"octubre ";)&SI(DIASEM(FECHA(A1;3;1);2)=5;"marzo ";)&SI(DIASEM(FECHA(A1;5;1);2)=5;"mayo ";)&SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=28;DIASEM(FECHA(A1;1;1);2)=6);"Julio ";)&SI(DIASEM(FECHA(A1;8;1);2)=5;"agosto ";)&SI(DIASEM(FECHA(A1;12;1);2)=5;"diciembre ";)&SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=28;DIASEM(FECHA(A1;1;1);2)=1);"ninguno ";)&SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=29;DIASEM(FECHA(A1;1;1);2)=7);"ninguno ";"")
Fórmula 4, Tiene las mismas funciones que la fórmula 1. La diferencia es que la 1 hace referencia a la fecha 1 de enero y esta para el 1 de marzo y cambia el orden de los meses como se indica a continuación: Para años bisiesto que empiezan en lunes (le corresponde octubre), martes (enero y julio), miércoles (diciembre), jueves (ninguno), viernes (marzo), sábado (agosto) y domingo (mayo) y los años que no son bisiestos lunes (enero y octubre), martes (julio), miércoles (diciembre); jueves (ninguno),viernes (marzo),sábado (agosto) y domingo (mayo).
Como la fórmula la celda A1 sólo contiene el año:
=SI(O(RESIDUO(A1;400)=0;Y(RESIDUO(A1;4)=0;RESIDUO(A1;100)<>0));ELEGIR(DIASEM(FECHA(A1;3;1);2);"octubre ";"enero y julio ";"diciembre ";"ninguno ";"marzo ";"agosto ";"mayo ");ELEGIR(DIASEM(FECHA(A1;3;1);2);"enero y octubre ";"julio ";"diciembre ";"ninguno ";"marzo ";"agosto ";"mayo "))
Fórmula 5: La siguiente fórmula hace referencia a la fecha 1 de marzo (el contenido de la celda A1 es sólo el año):
=SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=28;DIASEM(FECHA(A1;3;1);2)=1);"enero y octubre";) &SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=29;DIASEM(FECHA(A1;3;1);2)=1);"octubre ";) &SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=29;DIASEM(FECHA(A1;3;1);2)=2);"enero y julio ";) &SI(Y(DIA(FIN.MES(FECHA(A1;2;1);0))=28;DIASEM(FECHA(A1;3;1);2)=2);"julio ";)&SI(DIASEM(FECHA(A1;3;1);2)=3;"diciembre ";) &SI(DIASEM(FECHA(A1;3;1);2)=4;"ninguno ";) &SI(DIASEM(FECHA(A1;3;1);2)=5;"marzo ";) &SI(DIASEM(FECHA(A1;3;1);2)=6;"Agosto ";) &SI(DIASEM(FECHA(A1;3;1);2)=7;"mayo ";"")
Las siguientes fórmulas nos pueden servir de ayuda o referencia, donde se usa la función ELEGIR y con DIASEM le da un número índice (del 1 al 7). Por ejemplo, la función ELEGIR tiene que tener un número índice para que devuelva el argumento correspondiente según el orden, En la fórmula siguiente poniendo el número 3, devolvería el argumento que está en 3º posición que es miércoles:
=ELEGIR(3;"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ";"domingo ")
Si ponemos de número índice el 7, obtendríamos de resultado domingo, ya que está en la 7º posición:
=ELEGIR(7;"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ";"domingo ")
Donde se ha puesto el número 3 y 7 si en vez del número incluimos la función DIASEM, obtendríamos un número índice del (1 al 7), que corresponde al día de semana del 1 de enero. si ponemos tipo 2 devuelve el siguiente número: (1 para lunes;2 martes, 3 miércoles, 4 jueves, 5 viernes, 6 sábado y 7 domingo).
En la fórmula la celda A1, sólo contiene el año:
=ELEGIR(DIASEM(FECHA(A1;1;1);2);"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ";"domingo ")
En la siguiente fórmula la celda A1 contiene una fecha con el día, mes y año diferente al 1 de enero, aplicamos la siguiente fórmula:
=ELEGIR(DIASEM(FECHA(AÑO(A1);1;1);2);"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ";"domingo ")
En el caso de que la celda A1 esté vacía. podemos aplicar la siguiente fórmula:
=SI(ESBLANCO(A1);" ";ELEGIR(DIASEM(FECHA(A1;1;1);2);"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ";"domingo "))
Si la celda A1 contiene la fecha exacta con el día, mes y año, aplicamos la siguiente fórmula:
=ELEGIR(DIASEM(A1;2);"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ";"domingo ")
En el caso de incluir con la función DIASEM tipo 2, habría que cambiar el orden de los días de la semana como se indica a continuación:
=ELEGIR(DIASEM(A1);"domingo ";"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ")
La siguiente fórmula la celda A1 sólo contiene el año y devolvería el mismo resultado, sin poner tipo 2:
=ELEGIR(DIASEM(FECHA(A1;1;1));"domingo ";"lunes ";"martes ";"miércoles ";"jueves ";"viernes ";"sábado ")
La siguiente fórmula contiene varias condiciones con la función SI y DIASEM (con tipo 2). de las 7 pruebas lógicas devuelve la que corresponde al día de semana del 1 de enero del año que se encuentra en la celda A1
=SI(DIASEM(FECHA(A1;1;1);2)=1;"lunes ";)&SI(DIASEM(FECHA(A1;1;1);2)=2;"martes ";)&SI(DIASEM(FECHA(A1;1;1);2)=3;"miércoles ";)&SI(DIASEM(FECHA(A1;1;1);2)=4;"jueves ";)&SI(DIASEM(FECHA(A1;1;1);2)=5;"viernes ";)&SI(DIASEM(FECHA(A1;1;1);2)=6;"sábado ";)&SI(DIASEM(FECHA(A1;1;1);2)=7;"domingo ";)
Clic para Descargar la plantilla haciendo clic en el siguiente enlace: Plantilla varios aplica formato a los días de los meses que tienen 5 vi-sa y domingos
nota: la hoja se encuentra protegida para que no se borren las fórmulas (la contraseña está en blanco)