Excel Gratis

Para localizar los años idénticos que empiecen por el mismo día del año y diferenciando si son bisiestos o no se muestran varias fórmulas con diferentes funciones en hoja de Excel para localizar años idénticos en calendarios, para versiones antiguas y más modernas. En la hoja de Excel en la celda A1 tenemos que introducir una fecha con el día mes y año.

Versiones modernas de Excel que tenga la función FILTRAR y LET

Fórmula 1:: muestra los los años idénticos desde el año que se encuentra en la celda A1 hasta el año 2500, si queremos hasta el 5000, cambiamos en la fórmula el numero. En las celdas de la columna donde se pega la formula para mostrar los años tienen que estar vacías.


=FILTRAR(SECUENCIA(2500-AÑO(A1)+1; 1; AÑO(A1)); (DIASEM(FECHA(SECUENCIA(2500-AÑO(A1)+1; 1; AÑO(A1)); 1; 1); 2)=DIASEM(FECHA(AÑO(A1); 1; 1); 2)) * (MES(FECHA(SECUENCIA(2500-AÑO(A1)+1; 1; AÑO(A1)); 2; 29))=MES(FECHA(AÑO(A1); 2; 29))))

Fórmula 2: muestra los próximos 50 años idénticos, si queremos que nos muestre 100, cambiamos en la fórmula 50 por 100.


=LET(f;A1;a;AÑO(f);id;DIASEM(FECHA(a;1;1);2)&MES(FECHA(a;2;29));r;a+SECUENCIA(1500);TOMAR(FILTRAR(r;MAP(r;LAMBDA(x;DIASEM(FECHA(x;1;1);2)&MES(FECHA(x;2;29))=id)));50))

Fórmulas para versiones más antiguas de Excel

Las siguientes fórmulas que son matriciales tenemos que copiar y pegar en una celda vacía. Seleccionamos la fórmula y pulsamos conjuntamente las teclas (Ctrl + Mayús + Entrar). Tiene que quedar encerrada entre las llaves { } al principio y al final.

Fórmula 3: Fórmula matricial devuelve el próximo año idéntico hasta el 4000, que puede ser dentro de  6-11-12-28 incluso 40 años


=SUMAPRODUCTO(K.ESIMO.MENOR((AÑO($A$1)+FILA($A$1:$A$4000)) + ((DIASEM(FECHA(AÑO($A$1)+FILA($A$1:$A$4000);1;1))<>DIASEM(FECHA(AÑO($A$1);1;1))) + (DIA(FECHA(AÑO($A$1)+FILA($A$1:$A$4000);3;0))<>DIA(FECHA(AÑO($A$1);3;0))))*10000; FILA(A1)))

Fórmula 4: matricial, devuelve el próximo año idéntico


=AÑO(A1)+COINCIDIR(1;(DIASEM(FECHA(AÑO(A1)+FILA(INDIRECTO("1:50"));1;1);2)=DIASEM(FECHA(AÑO(A1);1;1);2))*(MES(FECHA(AÑO(A1)+FILA(INDIRECTO("1:50"));2;29))=MES(FECHA(AÑO(A1);2;29)));0)

Fórmula 5: devuelva el próximo año idéntico


=AÑO(A1)+SI(Y(DIASEM(FECHA(AÑO(A1)+6;1;1))=DIASEM(FECHA(AÑO(A1);1;1));MES(FECHA(AÑO(A1)+6;2;29))=MES(FECHA(AÑO(A1);2;29)));6;SI(Y(DIASEM(FECHA(AÑO(A1)+11;1;1))=DIASEM(FECHA(AÑO(A1);1;1));MES(FECHA(AÑO(A1)+11;2;29))=MES(FECHA(AÑO(A1);2;29)));11;SI(Y(DIASEM(FECHA(AÑO(A1)+12;1;1))=DIASEM(FECHA(AÑO(A1);1;1));MES(FECHA(AÑO(A1)+12;2;29))=MES(FECHA(AÑO(A1);2;29)));12;SI(Y(DIASEM(FECHA(AÑO(A1)+28;1;1))=DIASEM(FECHA(AÑO(A1);1;1));MES(FECHA(AÑO(A1)+28;2;29))=MES(FECHA(AÑO(A1);2;29)));28;40))))

Fórmula 6: devuelve el próximo año idéntico


=AÑO(A1)+MIN(SI(MES(FECHA(AÑO(A1)+{6;11;12;17;23;28;40};2;29))=MES(FECHA(AÑO(A1);2;29));SI(DIASEM(FECHA(AÑO(A1)+{6;11;12;17;23;28;40};1;1))=DIASEM(FECHA(AÑO(A1);1;1));{6;11;12;17;23;28;40})))

Fórmula 7: pegar en una celda y arrastrar hacia abajo devuelve los próximos años coincidentes.


=AGREGAR(15;6;AÑO($A$1)+FILA($A$1:$A$7999)/((DIASEM(FECHA(AÑO($A$1)+FILA($A$1:$A$7999);1;1))=DIASEM(FECHA(AÑO($A$1);1;1)))*(DIA(FECHA(AÑO($A$1)+FILA($A$1:$A$7999);3;0))=DIA(FECHA(AÑO($A$1);3;0))));FILA(A1))

==================================================================

Regla General:

Normalmente, un calendario bisiesto es idéntico cada 28 años, excepto en los cambios de siglo que no son bisiestos donde se pueden repetir a los 12 o 40 años)
Reajuste de los Siglos (2100, 2200, 2300, 2500 ). Estos años al no ser bisiestos, rompen el ciclo de 28 años y se se pueden repetir a los 12 o 40 años.
Ejemplo para el año 2100:
Los calendarios de los años: 2072, 2076, 2080, 2084 y 2088, hasta dentro de 40 años de cada uno no hay otro idéntico.
Los calendarios de los años: 2092 y 2096 tienen una repetición mas corta 12 años en cada uno para encontrar otro idéntico.
La Excepción del 2400 al ser bisiesto No hay interrupciones y se mantiene siempre el ciclo normal de 28 años

Secuencia Real de Bisiestos Idénticos