Excel Gratis

Plantillas de Excel gratis, sin contraseñas

0

Fórmula en Excel para localizar los años que el 25 de diciembre -Navidad- coincide en domingo


    Años que la Navidad coincide en domingo (25 diciembre): Fórmulas y Listado (1901-2100)

    Guía actualizada a enero de 2026

    ⚠️ Nota de compatibilidad: Estas fórmulas utilizan la función FILTRAR (FILTER), la cual solo está disponible en versiones actuales de Excel (Microsoft 365, Office 2021 o superior) y en Google Sheets.

    1. Fórmulas de Excel

    Versión en Español:


    // Todos los años:
    =FILTRAR(FILA(1901:2100); DIASEM(FECHA(FILA(1901:2100);12;25);2)=7)

    // Solo años bisiestos:
    =LET(a; FILA(1901:2100); FILTRAR(a; (DIASEM(FECHA(a;12;25);2)=7)*((RESIDUO(a;4)=0)*(RESIDUO(a;100)<>0)+(RESIDUO(a;400)=0))))

    Versión en Inglés (English version):


    // All years:
    =FILTER(ROW(1901:2100), WEEKDAY(DATE(ROW(1901:2100),12,25),2)=7)

    // Leap years only:
    =LET(a, ROW(1901:2100), FILTER(a, (WEEKDAY(DATE(a,12,25),2)=7)*((MOD(a,4)=0)*(MOD(a,100)<>0)+(MOD(a,400)=0))))

    2. Años con Navidad en Domingo

    A continuación, la lista generada entre el año 1901 y 2100.NARANJA son años bisiestos.

    1904
    1910
    1921
    1927
    1932
    1938
    1949
    1955
    1960
    1966
    1977
    1983
    1988
    1994
    2005
    2011
    2016
    2022
    2033
    2039
    2044
    2050
    2061
    2067
    2072
    2078
    2089
    2095

    Formulas: (compatible con versiones antiguas)
    La siguiente formula muestra el año de la celda A1 si se cumplen las 2 condiciones que sea bisiesto y el 25 y el 25 de diciembre coincida en domingo, en caso contrario deja la celda en blanco.
    =SI((DIASEM(FECHA(A1;12;25);2)=7)*((RESIDUO(A17;4)=0)*(RESIDUO(A17;100)<>0)+(RESIDUO(A1;400)=0));A1;" ")

    La siguiente muestra los años que el 25 de diciembre es domingo, pero que no son bisiestos.
    =SI((DIASEM(FECHA(A1;12;25);2)=7)*((RESIDUO(A1;4)=0)*(RESIDUO(A1;100)<>0)+(RESIDUO(A1;400)<>0));A1;" ")

    La siguiente muestra si el 25 de diciembre coincide en domingo, en caso contrario devuelve (no coincide).
    =SI((DIASEM(FECHA(A1;12;25);2)=7);A1;"no coincide")

    Para contar los años desde 1901 hasta el 2100, que sean bisiestos y el 25 de diciembre coincida en domingo con la función SUMAPRODUCTO como se indica a continuación.

    =SUMAPRODUCTO((DIASEM(FECHA(FILA(1901:2100);12;25);2)=7)*((RESIDUO(FILA(1901:2100);4)=0)*(RESIDUO(FILA(1901:2100);100)<>0)+(RESIDUO(FILA(1901:2100);400)=0)))
    Para que cuente todos los años que coinciden en domingo
    =SUMAPRODUCTO((DIASEM(FECHA(FILA(1901:2100);12;25);2)=7)*1)

    =SUMAPRODUCTO(--(DIASEM(FECHA(FILA(1901:2100);12;25);2)=7))

    sin poner tipo 2 para contar
    =SUMAPRODUCTO((DIASEM(FECHA(FILA(1901:2100);12;25))=1)*1)

    Versión en inglés: para que devuelva los años que cumplan 2 condiciones: que el año que está en la celda A1 sea bisiesto y el 25 de diciembre coincidir en domingo

    =(WEEKDAY(DATE(A1,12,25),2)=7)*((MOD(A1,4)=0)*(MOD(A1,100)<>0)+(MOD(A1,400)=0))

    Para contar los años desde 1901 hasta 2100 que sean bisiestos y el 25 de diciembre coincida en domingo

    =SUMPRODUCT((WEEKDAY(DATE(ROW(1901:2100),5,25),2)=7)*((MOD(ROW(1901:2100),4)=0)*(MOD(ROW(1901:2100),100)<>0)+(MOD(ROW(1901:2100),400)=0)))

Hojas de Excel gratis
Excel gratis Posted2 days ago

Comments are closed.